| Server IP : 85.214.239.14 / Your IP : 18.220.7.116 Web Server : Apache/2.4.62 (Debian) System : Linux h2886529.stratoserver.net 4.9.0 #1 SMP Tue Jan 9 19:45:01 MSK 2024 x86_64 User : www-data ( 33) PHP Version : 7.4.18 Disable Function : pcntl_alarm,pcntl_fork,pcntl_waitpid,pcntl_wait,pcntl_wifexited,pcntl_wifstopped,pcntl_wifsignaled,pcntl_wifcontinued,pcntl_wexitstatus,pcntl_wtermsig,pcntl_wstopsig,pcntl_signal,pcntl_signal_get_handler,pcntl_signal_dispatch,pcntl_get_last_error,pcntl_strerror,pcntl_sigprocmask,pcntl_sigwaitinfo,pcntl_sigtimedwait,pcntl_exec,pcntl_getpriority,pcntl_setpriority,pcntl_async_signals,pcntl_unshare, MySQL : OFF | cURL : OFF | WGET : ON | Perl : ON | Python : ON | Sudo : ON | Pkexec : OFF Directory : /proc/2/task/2/root/proc/2/root/usr/share/doc/libparse-recdescent-perl/examples/ |
Upload File : |
#!/usr/bin/perl -ws
# THE COMMONEST REASON FOR WANTING LEFT RECURSION
use strict;
use Parse::RecDescent; $::RD_HINT = 1;
my $parse = Parse::RecDescent->new(<<'EndGrammar');
main: expr /\Z/ { $item[1] }
| <error>
expr: left_assoc[qw{term add_op term}]
| term
add_op: '+' { sub { $_[0] + $_[1] } }
| '-' { sub { $_[0] - $_[1] } }
term: left_assoc[qw{factor mult_op factor}]
| factor
mult_op: '*' { sub { $_[0] * $_[1] } }
| '/' { sub { $_[0] / $_[1] } }
factor: number
| '(' expr ')' { $item[2] }
number: /[-+]?\d+(\.\d+)?/
# THE BLACK MAGIC THAT MAKES IT WORK...
left_assoc: left_assoc_left[@arg[0,1]](s) <matchrule:$arg[2]>
{ my @terms = $item[1]
? ((map { @$_ } @{$item[1]}), $item[2])
: $item[1];
splice @terms, 0, 3, $terms[1]->(@terms[0,2])
while @terms>1;
$terms[0];
}
left_assoc_left: <matchrule:$arg[0]> <matchrule:$arg[1]>
{ [ @item[1..2] ] }
EndGrammar
while (<DATA>) {
print $parse->main($_), "\n";
}
__DATA__
+1-1+1-1+1-1+1-1+1
7*7-6*8
121/(121/11)/121*11
1/(10-1/(1/(10-1)))