| Server IP : 85.214.239.14 / Your IP : 3.135.247.24 Web Server : Apache/2.4.62 (Debian) System : Linux h2886529.stratoserver.net 4.9.0 #1 SMP Tue Jan 9 19:45:01 MSK 2024 x86_64 User : www-data ( 33) PHP Version : 7.4.18 Disable Function : pcntl_alarm,pcntl_fork,pcntl_waitpid,pcntl_wait,pcntl_wifexited,pcntl_wifstopped,pcntl_wifsignaled,pcntl_wifcontinued,pcntl_wexitstatus,pcntl_wtermsig,pcntl_wstopsig,pcntl_signal,pcntl_signal_get_handler,pcntl_signal_dispatch,pcntl_get_last_error,pcntl_strerror,pcntl_sigprocmask,pcntl_sigwaitinfo,pcntl_sigtimedwait,pcntl_exec,pcntl_getpriority,pcntl_setpriority,pcntl_async_signals,pcntl_unshare, MySQL : OFF | cURL : OFF | WGET : ON | Perl : ON | Python : ON | Sudo : ON | Pkexec : OFF Directory : /proc/3/cwd/proc/3/root/usr/share/augeas/lenses/dist/ |
Upload File : |
(*
Module: Nsswitch
Parses /etc/nsswitch.conf
Author: Raphael Pinson <raphink@gmail.com>
About: Reference
This lens tries to keep as close as possible to `man nsswitch.conf` where possible.
About: Licence
This file is licensed under the LGPL v2+, like the rest of Augeas.
About: Lens Usage
About: Configuration files
This lens applies to /etc/nsswitch.conf. See <filter>.
*)
module Nsswitch =
autoload xfm
(************************************************************************
* Group: USEFUL PRIMITIVES
*************************************************************************)
(* View: comment *)
let comment = Util.comment
(* View: empty *)
let empty = Util.empty
(* View: sep_colon
The separator for database entries *)
let sep_colon = del /:[ \t]*/ ": "
(* View: database_kw
The database specification like `passwd', `shadow', or `hosts' *)
let database_kw = Rx.word
(* View: service
The service specification like `files', `db', or `nis' *)
let service = [ label "service" . store Rx.word ]
(* View: reaction
The reaction on lookup result like `[NOTFOUND=return]'
TODO: Use case-insensitive regexps when ticket #147 is fixed.
*)
let reaction =
let status_kw = /[Ss][Uu][Cc][Cc][Ee][Ss][Ss]/
| /[Nn][Oo][Tt][Ff][Oo][Uu][Nn][Dd]/
| /[Uu][Nn][Aa][Vv][Aa][Ii][Ll]/
| /[Tt][Rr][Yy][Aa][Gg][Aa][Ii][Nn]/
in let action_kw = /[Rr][Ee][Tt][Uu][Rr][Nn]/
| /[Cc][Oo][Nn][Tt][Ii][Nn][Uu][Ee]/
| /[Mm][Ee][Rr][Gg][Ee]/
in let negate = [ Util.del_str "!" . label "negate" ]
in let reaction_entry = [ label "status" . negate?
. store status_kw
. Util.del_str "="
. [ label "action" . store action_kw ] ]
in Util.del_str "["
. [ label "reaction"
. (Build.opt_list reaction_entry Sep.space) ]
. Util.del_str "]"
(* View: database *)
let database =
[ label "database" . store database_kw
. sep_colon
. (Build.opt_list
(service|reaction)
Sep.space)
. Util.comment_or_eol ]
(* View: lns *)
let lns = ( empty | comment | database )*
(* Variable: filter *)
let filter = (incl "/etc/nsswitch.conf")
let xfm = transform lns filter