| Server IP : 85.214.239.14 / Your IP : 13.59.54.188 Web Server : Apache/2.4.62 (Debian) System : Linux h2886529.stratoserver.net 4.9.0 #1 SMP Tue Jan 9 19:45:01 MSK 2024 x86_64 User : www-data ( 33) PHP Version : 7.4.18 Disable Function : pcntl_alarm,pcntl_fork,pcntl_waitpid,pcntl_wait,pcntl_wifexited,pcntl_wifstopped,pcntl_wifsignaled,pcntl_wifcontinued,pcntl_wexitstatus,pcntl_wtermsig,pcntl_wstopsig,pcntl_signal,pcntl_signal_get_handler,pcntl_signal_dispatch,pcntl_get_last_error,pcntl_strerror,pcntl_sigprocmask,pcntl_sigwaitinfo,pcntl_sigtimedwait,pcntl_exec,pcntl_getpriority,pcntl_setpriority,pcntl_async_signals,pcntl_unshare, MySQL : OFF | cURL : OFF | WGET : ON | Perl : ON | Python : ON | Sudo : ON | Pkexec : OFF Directory : /proc/2/cwd/usr/share/augeas/lenses/dist/ |
Upload File : |
(*
Module: Sysconfig_Route
Parses /etc/sysconfig/network-scripts/route-${device}
Author: Stephen P. Schaefer
About: Reference
This lens allows manipulation of *one* IPv4 variant of the
/etc/sysconfig/network-scripts/route-${device} script found in RHEL5+, CentOS5+
and Fedora.
The variant handled consists of lines like
"destination_subnet/cidr via router_ip", e.g.,
"10.132.11.0/24 via 10.10.2.1"
There are other variants; if you use them, please enhance this lens.
The natural key would be "10.132.11.0/24" with value "10.10.2.1", but since
augeas cannot deal with slashes in the key value, I reverse them, so that the
key is "10.10.2.1[1]" (and "10.10.2.1[2]"... if multiple subnets are reachable
via that router).
About: License
This file is licenced under the LGPL v2+, like the rest of Augeas.
About: Lens Usage
Sample usage of this lens in augtool
* Set the first subnet reachable by a router reachable on the eth0 subnet
> set /files/etc/sysconfig/network-scripts/route-eth0/10.10.2.1[1] 172.16.254.0/24
* List all the subnets reachable by a router reachable on eth0 subnet
> match /files/etc/sysconfig/network-scripts/route-eth0/10.10.2.1
About: Configuration files
This lens applies to /etc/sysconfig/network-scripts/route-*
About: Examples
The <Test_Sysconfig_Route> file contains various examples and tests.
*)
module Sysconfig_Route =
autoload xfm
(******************************************************************************
* Group: USEFUL PRIMITIVES
******************************************************************************)
(* Variable: router
A router *)
let router = Rx.ipv4
(* Variable: cidr
A subnet mask can be 0 to 32 bits *)
let cidr = /(3[012]|[12][0-9]|[0-9])/
(* Variable: subnet
Subnet specification *)
let subnet = Rx.ipv4 . "/" . cidr
(******************************************************************************
* Group: ENTRY TYPES
******************************************************************************)
(* View: entry
One route *)
let entry = [ store subnet . del /[ \t]*via[ \t]*/ " via "
. key router . Util.del_str "\n" ]
(******************************************************************************
* Group: LENS AND FILTER
******************************************************************************)
(* View: lns *)
let lns = entry+
(* View: filter *)
let filter = incl "/etc/sysconfig/network-scripts/route-*"
. Util.stdexcl
let xfm = transform lns filter